This page has 0 threads | Add post

Reading and Writing Text Files using TextStreams

Written by Andy Brown

In this tutorial

What this Example Does
Referencing the FileSystemObject
Creating a New Text File
Writing Out Lines of Text and Closing the File
A Summary of the Entire Routine
Sample Code to Loop Over Lines
More on the OpenTextFile Method

This tutorial shows how to read from (and write to) text files using something called TextStream objects.

There is another way to do this in VBA using commands like Input and Open, but I think the way shown here is much easier to remember and use.

In order to get any of the code in this tutorial to work, you first need to create a FileSystemObject.

What this Example Does

The code on this page will create a new text file on your hard disk:

The code will create the file called info.txt on your hard disk.

Here's what the contents of the text file will look like:

The code will write out the two lines!

Referencing the FileSystemObject

The first thing we need to do is to create a reference to the Microsoft Scripting Runtime object library, and then create a FileSystemObject - refer to my separate FileSystemObject tutorial for how to do this and what it means:

Sub CreateFile()

'we need this, even though it doesn't make much sense!

Dim fso As New FileSystemObject

Creating a New Text File

To do this, apply the CreateTextFile method to the weird FileSystemObject:

'the file we're going to write to

Dim ts As TextStream

'open this file to write to it

Set ts = fso.CreateTextFile("C:\Wise Owl\info.txt", True)

In this case, the second argument True refers to whether we'll overwrite any existing version of the file when we create the new one. We choose to do so.

Writing Out Lines of Text and Closing the File

You can use the WriteLine method to write lines of text, but you must then close the file:

'write out a couple of lines

ts.WriteLine ("If anyone finds this file")

ts.WriteLine ("they will wonder who created it")

'close down the file

ts.Close

End Sub

A Summary of the Entire Routine

Here's the entire routine for ease of copying and reference:

Sub CreateFile()

'we need this, even though it doesn't make much sense!

Dim fso As New FileSystemObject

'the file we're going to write to

Dim ts As TextStream

'open this file to write to it

Set ts = fso.CreateTextFile("C:\Wise Owl\info.txt", True)

'write out a couple of lines

ts.WriteLine ("If anyone finds this file")

ts.WriteLine ("they will wonder who created it")

'close down the file

ts.Close

End Sub

Now that we've successfully created a text file, how can we read it in? To do this, we need to open another TextStream object.

Sample Code to Loop Over Lines

Having created a text file, here's some code to read it in. The trick is to keep reading lines until we reach the end of the text stream:

Sub ReadFile()

'again, we need this strange thing to exist so that ...

Dim fso As New FileSystemObject

'the file we're going to read from

Dim ts As TextStream

'... we can open a text file with reference to it

Set ts = fso.OpenTextFile("C:\Wise Owl\info.txt", ForReading)

'keep reading in lines till no more

Dim ThisLine As String

Dim i As Integer

i = 0

Do Until ts.AtEndOfStream

ThisLine = ts.ReadLine

i = i + 1

Debug.Print "Line " & i, ThisLine

Loop

'close down the file

ts.Close

End Sub

Here's what this would show in the immediate window:

The routine prints out the lines to the immediate window

More on the OpenTextFile Method

When you choose to open a text file, you can do it in one of 3 ways:

The 3 possible ways to open a text stream

In our example we wanted to read from the file, but you can also use the OpenTextFile method to open a file to write more lines to it (using ForAppending).

Previous
tutorial

Referencing applications

Previous
part

Creating a FileSystemObject

Top of page

Next
part

Working with Files and Folders

Next
tutorial

Working with databases

You can learn more about this topic on the following Wise Owl courses:

This page has 0 threads

Add a new post

Online tutorials

Tutorials on VBA

Working with files and folders

Reading and Writing Text Files using TextStreams

What this Example Does

Referencing the FileSystemObject

Creating a New Text File

Writing Out Lines of Text and Closing the File

A Summary of the Entire Routine

Sample Code to Loop Over Lines

More on the OpenTextFile Method

Head office

London

Manchester